VBS: Управление точками восстановления Windows

'********************************************************************

' Restore point type

'********************************************************************

Const APPLICATION_INSTALL = 0

Const APPLICATION_UNINSTALL = 1

Const DEVICE_DRIVER_INSTALL = 10

Const MODIFY_SETTINGS = 12

Const CANCELLED_OPERATION = 13

'********************************************************************

' Restore point event type

'********************************************************************

Const BEGIN_NESTED_SYSTEM_CHANGE = 102

Const BEGIN_SYSTEM_CHANGE = 100

Const END_NESTED_SYSTEM_CHANGE = 103

Const END_SYSTEM_CHANGE = 101

'********************************************************************

' Локализация

'********************************************************************

Const strCreateSystemRestorePoint0 = "Создана скриптом "

Const strCreateSystemRestorePoint1 = "Создаём точку восстановления системы."

Const strCreateSystemRestorePoint2 = "Точка восстановления создана успешно."

Const strCreateSystemRestorePoint3 = "Не удалось создать точку восстановления."

Const strDisableSystemRestore1 = "Отключаем восстановление системы для всех дисков."

Const strDisableSystemRestore2 = "Отключение восстановления системы прошло успешно."

Const strDisableSystemRestore3 = "Отключение восстановления системы прошло с ошибками."

Const strEnableSystemRestore1 = "Включаем восстановление системы для всех дисков."

Const strEnableSystemRestore2 = "Включение восстановления системы прошло успешно."

Const strEnableSystemRestore3 = "Включение восстановления системы прошло с ошибками."

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' Процедура CreateSystemRestorePoint()

' Описание: Создаём точку восстановления системы

' Вход : Нет

' Выход : Нет

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub CreateSystemRestorePoint ()

Dim objWMIService, objItem, errResults

WScript.Echo strCreateSystemRestorePoint1

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default")

Set objItem = objWMIService.Get("SystemRestore")

errResults = objItem.CreateRestorePoint _

(strCreateSystemRestorePoint0 & """" & strPrompt & """", _

CANCELLED_OPERATION, BEGIN_SYSTEM_CHANGE)

If errResults=0 Then

WScript.Echo strCreateSystemRestorePoint2

Else

WScript.Echo strCreateSystemRestorePoint3

End If

Set objItem = Nothing

Set objWMIService = Nothing

End Sub

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' Процедура DisableSystemRestore()

' Описание: Отключение восстановления системы для всех дисков

' Вход : Нет

' Выход : Нет

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub DisableSystemRestore ()

Dim objWMIService, objItem, errResults

WScript.Echo strDisableSystemRestore1

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default")

Set objItem = objWMIService.Get("SystemRestore")

errResults = objItem.Disable("")

If errResults=0 Then

WScript.Echo strDisableSystemRestore2

Else

WScript.Echo strDisableSystemRestore3

End If

Set objItem = Nothing

Set objWMIService = Nothing

End Sub

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' Процедура EnableSystemRestore()

' Описание: Включение восстановления системы для всех дисков

' Вход : Нет

' Выход : Нет

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub EnableSystemRestore ()

Dim objWMIService, objItem, errResults

WScript.Echo strEnableSystemRestore1

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default")

Set objItem = objWMIService.Get("SystemRestore")

errResults = objItem.Enable("")

If errResults=0 Then

WScript.Echo strEnableSystemRestore2

Else

WScript.Echo strEnableSystemRestore3

End If

Set objItem = Nothing

Set objWMIService = Nothing

End Sub

Источник: http://forum.vingrad.ru/topic-216596.html